@echo off
cd /d "%~dp0"
echo 処理対象:"%~nx1"
echo ***************************************************
echo フレームレートを指定して、実行キーを押してください。
echo.
echo 数字   "規格名"      比率
echo 29.97  "ntsc_video" 30000,1001
echo.
echo 23.976 "ntsc_film"  24000,1001
echo.
echo ここでは「ソースレートの調整」を行います。
echo コーデックチェッカーで調べた、極力正確なフレームレートを指定します。
echo "規格名"または、比率で指定することもできます(推奨)。
echo 29.97と指定するより"ntsc_video"あるいは、30000,1001と指定します。
echo.
set /p framerate1=ソースレートの調整:
set framerate1=%framerate1%
echo.
echo 「ソースレートの調整」は、%framerate1%に設定されました。
echo.
echo つぎに「フレームレートの変換」を行います。
echo 新たに設定するフレームレートを小数第2位までの数字で指定してください。
echo たとえば、「ソースレートの調整」が23.976の場合、「フレームレートの変換」は23.98あたりを指定します。
echo.
set /p framerate2=フレームレートの変換:
set framerate2=%framerate2%
echo.
echo 「フレームレートの変換」は、%framerate2%fpsに設定されました。
echo.
pause
if "%~x1"==".mp4" goto mp4
if "%~x1"==".MP4" goto mp4
tools\ffmpeg\ffmpeg -y -i "%~1" -vn "%~dpn1.wav"
goto avs
:mp4
neroaacdec -if "%~1" -of "%~dpn1.wav"
goto avs
:avs
echo LoadPlugin("%~dp0FFMS2.dll")>"%~dpn1_ffms2.avs"
echo ffvideosource("%~1")>>"%~dpn1_ffms2.avs"
echo a=wavsource("%~dpn1.wav").Normalize>>"%~dpn1_ffms2.avs"
echo audiodub(a)>>"%~dpn1_ffms2.avs"
echo AssumeFPS(%framerate1%)>>"%~dpn1_ffms2.avs"
echo convertfps(%framerate2%)>>"%~dpn1_ffms2.avs"
echo #delayaudio()>>"%~dpn1_ffms2.avs"
echo #info()>>"%~dpn1_ffms2.avs"